astra-client-docs-tests/build.gradle.kts at master · datastax/astra-client-docs-tests · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
plugins {
    java
    application
}

group = "com.dtsx.docs"
version = "1.0.0-alpha.1"

repositories {
    mavenCentral()
}

dependencies {
    // cli stuff
    implementation("info.picocli:picocli:4.7.7")
    annotationProcessor("info.picocli:picocli-codegen:4.7.7")
    implementation("info.picocli:picocli-codegen:4.7.7")

    // snapshot testing
    implementation("com.approvaltests:approvaltests:25.0.23")

    // test settings from .env files
    implementation("io.github.cdimascio:dotenv-java:3.2.0")

    // shuts up some errors about missing SLF4J implementations
    implementation("org.slf4j:slf4j-nop:2.0.17")

    // yaml
    implementation("tools.jackson.dataformat:jackson-dataformat-yaml:3.0.3")
    implementation("tools.jackson.core:jackson-databind:3.0.3")

    // static utils
    compileOnly("org.jetbrains:annotations:26.0.2")
    compileOnly("org.projectlombok:lombok:1.18.42")
    annotationProcessor("org.projectlombok:lombok:1.18.42")

    // other utils
    implementation("commons-io:commons-io:2.21.0")

    // no idea what this is :)
    implementation("com.datastax.astra:astra-db-java:2.1.4")
}

application {
    applicationDefaultJvmArgs = listOf("--enable-native-access=ALL-UNNAMED")
    mainClass.set("com.dtsx.docs.HelperCli")
}

tasks.register<Jar>("fatJar") {
    dependsOn(configurations.runtimeClasspath)

    group = "build"
    description = "fat jar"

    archiveFileName.set("verifier.jar")
    archiveVersion.set(project.version.toString())

    duplicatesStrategy = DuplicatesStrategy.EXCLUDE

    manifest {
        attributes["Main-Class"] = "com.dtsx.docs.HelperCli"
    }

    from(sourceSets.main.get().output)

    from({
        configurations.runtimeClasspath.get().filter { it.name.endsWith("jar") }.map { zipTree(it) }
    })
}