dooit/flake.nix at main · dooit-org/dooit · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
{
  description = "Flake for Dooit with default.nix integration";

  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
  };

  outputs =
    {
      self,
      nixpkgs,
      ...
    }:
    let
      forEachSystem = nixpkgs.lib.genAttrs nixpkgs.lib.platforms.all;

      pkgsFor = forEachSystem (
        system:
        import nixpkgs {
          inherit system;
        }
      );

      packageFor = system: pkgsFor.${system}.callPackage ./nix { };
    in
    {
      packages = forEachSystem (system: {
        default = packageFor system;
      });
      overlay = final: prev: {
        dooit = packageFor final.system;
      };

      homeManagerModules = {
        default = self.homeManagerModules.dooit;
        dooit = import ./nix/hm-module.nix self;
      };

      devShells = forEachSystem (
        system:
        let
          pkgs = pkgsFor.${system};
        in
        {
          default = pkgs.mkShell {
            buildInputs = with pkgs; [
              nodejs
              nodePackages.yarn
              nodePackages.npm
            ];
          };
        }
      );
    };
}