kanban/flake.nix at develop · fulsomenko/kanban · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
{
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
    rust-overlay.url = "github:oxalica/rust-overlay";
    flake-utils.url = "github:numtide/flake-utils";
    servers.url = "github:fulsomenko/servers";
  };

  outputs = {
    self,
    nixpkgs,
    rust-overlay,
    flake-utils,
    servers,
    ...
  }:
    flake-utils.lib.eachDefaultSystem (
      system: let
        overlays = [(import rust-overlay)];
        pkgs = import nixpkgs {
          inherit system overlays;
        };

        rustToolchain = pkgs.rust-bin.stable.latest.default.override {
          extensions = ["rust-src" "rust-analyzer" "clippy" "rustfmt"];
        };

        changeset = pkgs.writeShellApplication {
          name = "changeset";
          runtimeInputs = with pkgs; [coreutils];
          text = builtins.readFile ./scripts/create-changeset.sh;
        };

        bumpVersion = pkgs.writeShellApplication {
          name = "bump-version";
          runtimeInputs = with pkgs; [rustToolchain cargo coreutils gnugrep gnused git findutils];
          text = builtins.readFile ./scripts/bump-version.sh;
        };

        publishCrates = pkgs.writeShellApplication {
          name = "publish-crates";
          runtimeInputs = [rustToolchain pkgs.cargo pkgs.coreutils validateRelease];
          text = builtins.readFile ./scripts/publish-crates.sh;
        };

        aggregateChangelog = pkgs.writeShellApplication {
          name = "aggregate-changelog";
          runtimeInputs = with pkgs; [coreutils gnugrep gnused git findutils];
          text = builtins.readFile ./scripts/aggregate-changelog.sh;
        };

        validateRelease = pkgs.writeShellApplication {
          name = "validate-release";
          runtimeInputs = with pkgs; [rustToolchain cargo coreutils gnugrep gnused];
          text = builtins.readFile ./scripts/validate-release.sh;
        };
      in {
        devShells.default = import ./shell.nix {
          inherit pkgs rustToolchain;
          inherit changeset aggregateChangelog bumpVersion publishCrates validateRelease;
        };

        packages = let
          kanban = pkgs.callPackage ./default.nix {};
        in {
          default = kanban;
          kanban-mcp = pkgs.callPackage ./crates/kanban-mcp/default.nix {
            inherit kanban;
          };
          kanban-web = pkgs.callPackage ./web/default.nix {};
          mcp-server-git = servers.packages.${system}.mcp-server-git;
          aggregate-changelog = aggregateChangelog;
          bump-version = bumpVersion;
          publish-crates = publishCrates;
          validate-release = validateRelease;
          changeset = changeset;
        };
      }
    );
}