simplemem/flake.nix at main · jcdickinson/simplemem · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
{
  description = "A simple semantic memory MCP.";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    flake-utils.url = "github:numtide/flake-utils";
    gomod2nix-input = {
      url = "github:nix-community/gomod2nix";
      inputs = {
        nixpkgs.follows = "nixpkgs";
        flake-utils.follows = "flake-utils";
      };
    };
  };

  outputs = {
    self,
    nixpkgs,
    flake-utils,
    gomod2nix-input,
  }: (flake-utils.lib.eachDefaultSystem (
    system: let
      pkgs = nixpkgs.legacyPackages.${system};
      gomod2nix = gomod2nix-input.legacyPackages.${system};

      inherit (pkgs) callPackage;

      go-test = pkgs.stdenvNoCC.mkDerivation {
        name = "go-test";
        dontBuild = true;
        src = ./.;
        doCheck = true;
        nativeBuildInputs = with pkgs; [
          go
          writableTmpDirAsHomeHook
        ];
        checkPhase = ''
          go test -v ./...
        '';
        installPhase = ''
          mkdir "$out"
        '';
      };
      # Simple lint check added to nix flake check
      go-lint = pkgs.stdenvNoCC.mkDerivation {
        name = "go-lint";
        dontBuild = true;
        src = ./.;
        doCheck = true;
        nativeBuildInputs = with pkgs; [
          golangci-lint
          go
          writableTmpDirAsHomeHook
        ];
        checkPhase = ''
          golangci-lint run
        '';
        installPhase = ''
          mkdir "$out"
        '';
      };
    in {
      formatter = pkgs.alejandra;
      checks = {
        inherit go-test go-lint;
      };
      packages = {
        simplemem = callPackage ./default.nix {
          inherit (gomod2nix) buildGoApplication;
          pname = "simplemem";
          subPackages = ["cmd/simplemem"];
          meta = {
            mainProgram = "simplemem";
          };
        };
        default = callPackage ./default.nix {
          inherit (gomod2nix) buildGoApplication;
        };
      };
      devShells.default = callPackage ./shell.nix {
        inherit (gomod2nix) mkGoEnv gomod2nix;
      };
    }
  ));
}