upper triangle question

[justin2004]

∘.<⍨∘⍳Js               Upper triangular matrix without diagonal: Js by Js

do we need the jot?
e.g.

∘.<⍨∘⍳ 5
vs.
∘.<⍨⍳ 5

[abrudz]

This is so that it becomes a stand-alone function. The entry could have said (∘.<⍨⍳)Js instead, but note that technically, (∘.<⍨⍳)5 is not the same as ∘.<⍨⍳5 because the former derives a new function using the Atop construct while the latter is simply an inline expression where ∘.<⍨ and ⍳ are not connected in any way other than the flow of computation. APLcart's table is a bit inconsistent in that some functions consisting of two consecutive monadic functions are written f∘g while others are written (f g) ― but both forms are of course valid.

The entries are intentionally valid functions so they can be copied and named without needing manipulation.

[justin2004]

does this not demonstrate that both are stand-alone functions?

      f←∘.<⍨⍳
      g←∘.<⍨∘⍳
      f 5
0 1 1 1 1
0 0 1 1 1
0 0 0 1 1
0 0 0 0 1
0 0 0 0 0
      g 5
0 1 1 1 1
0 0 1 1 1
0 0 0 1 1
0 0 0 0 1
0 0 0 0 0

[abrudz]

This demonstrates that ∘.<⍨⍳ is a stand-alone function, yes, but in the expression ∘.<⍨⍳5 there are two functions being applied: First ⍳ is applied to 5 and then ∘.<⍨ is applied to 1 2 3 4 5. The difference in (∘.<⍨⍳)5 is that the two separate functions are bound into a single stand-alone function, which is then applied. In this case, the result is the same, but e.g. 4(÷-)2 is not the same as 4÷-2 for the former gives 0.5 and the latter gives ¯2. In this case we have 4÷∘-2 equivalent to 4÷-2 but not to 4(÷-)2 because the former gives ¯2 and the latter gives 0.5.

[justin2004]

ah, the 4(÷-)2 makes it clear why you said that (∘.<⍨⍳)5 uses the Atop construct.
i wasn't thinking about function trains.

thanks for the explanation!