Treewide: Convert Hugo callouts to GFM alerts

[Bugg4]

This converts all the Hugo style callouts to GFM alerts.
For example, this

{{< callout type=info >}}

To get the correct name for an `unmodified_key`, refer to [the section on uncommon syms](#uncommon-syms--binding-with-a-keycode)

{{< /callout >}}

gets converted to:

> [!NOTE]
> To get the correct name for an `unmodified_key`, refer to [the section on uncommon syms](#uncommon-syms--binding-with-a-keycode)

This is related to #1198 and it's meant make the codebase easier to lint by using standard markdown where possible, reducing Hugo specific markup to a minimum.

Some notes on the automated conversion that has been performed:

• Callouts of type warning, important and info got converted to [!WARNING], [!IMPORTANT] and [!NOTE] respectively.
• All callouts that did not have a type got converted to [!WARNING] by default, since they were highlighted in orange by Hugo. This will maintain visual continuity.
• Blank lines after the opening markup ({{< callout type=warning >}}) and before the closing markup ({{</ callout >}}) were trimmed.
• Blank lines mid-content were kept
• See Meta: Introduce linting tools #1198 (comment) for a visual example of how they render before and after.

I'll include the script that I used here for documenation's sake, but let me know if I should push it to the repo:

(Can just be run from the repo's root, without args)

hugo-callouts-to-gfm-alerts.pl

#!/usr/bin/env perl
use strict;
use warnings;
use File::Find;

# Mapping from hugo callout type -> GFM alert type
my %map = (
    info      => 'NOTE',
    warning   => 'WARNING',
    important => 'IMPORTANT',
);

sub transform {
    my ($text) = @_;

    $text =~ s{
        \{\{<\s*callout(?:\s+type=(\w+))?\s*>\}\}   # opening shortcode
        (.*?)                                       # body
        \{\{<\s*/?\s*callout\s*>\}\}                # closing shortcode (forgiving of malformed closing tags)
    }{
        my $type = $1 // 'warning';
        my %map  = (info=>'NOTE', warning=>'WARNING', important=>'IMPORTANT');
        my $hdr  = $map{lc $type} // uc($type);
        my $body = $2;

        # Trim leading/trailing newlines inside the callout
        $body =~ s/^\n+//;
        $body =~ s/\n+$//;

        # If the very first line is empty, drop it
        $body =~ s/^\s*\n//;

        # Prefix all lines (including blanks) with "> "
        $body =~ s/^/> /mg;

        "> [!$hdr]\n$body"
    }egsx;

    return $text;
}


sub process_file {
    my ($file) = @_;
    return unless $file =~ /\.md$/i;

    local $/ = undef;
    open my $fh, '<', $file or die "Cannot open $file: $!";
    my $content = <$fh>;
    close $fh;

    my $new = transform($content);

    if ($new ne $content) {
        open my $out, '>', $file or die "Cannot write $file: $!";
        print $out $new;
        close $out;
        print "Transformed: $file\n";
    }
}

my $root = shift @ARGV // 'content';
find(
    {
        wanted   => sub { process_file($File::Find::name) if -f },
        no_chdir => 1,
    },
    $root
);

If this is merged, we may want to consider adding a note about the new alert style to the Contributing to the WIki section the README, to inform contributors about the change. Let me know if you want it mentioned and I'll add it.

Marked as draft as I skimmed about 20-25 pages opening them at random to check alerts looked correct, but did not confirm each and every conversion went well, aside from looking at the diff.
An additional pair of eyes is welcomed :)
I'll give a more thorough look to all pages if we decide to go forward with this ✌️

[fufexan]

one miss, rest lgtm.

[Bugg4]

Ok, will mark as ready for merge once I skimmed all the pages

[Bugg4]

Ready for merge

[fufexan]

Thanks, LGTM